home *** CD-ROM | disk | FTP | other *** search
/ Ham Radio 2000 / Ham Radio 2000.iso / ham2000 / morse / staton / cpo_spk.txt < prev    next >
Text File  |  1994-04-22  |  10KB  |  524 lines
  1. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!;
  2. ;   COPYRIGHT (C) 1994 KEN STATON    ;
  3. ;         ALL RIGHTS RESERVED        ;
  4. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!;
  5.  
  6. #INCLUDE "GLOBALS.TXT"
  7.     .MSFIRST                ; MOST SIGNIFICANT BYTE FIRST!
  8.  
  9. ;
  10. ;       Ken Staton
  11. ;       Feb 9, 1993     First coding
  12. ;       Apr 3, 1993     Added DAC support
  13. ;               ~44K of digitized speech: 
  14. ;             A-Z = 26 + 0-9 = 10 + {.,?} = 3 total = 39
  15. ;             {sk,bt,ar,dn,kn} = 5; 39 + 5 = 44
  16. ;             could implement {sk,bt,ar,dn,kn} as 
  17. ;             concatenations of letters
  18. ;       Jun 3, 1993     Added ADPCM digitized speech
  19. ;    Aug 17, 1993    Cleanup.  Removed Debug & RS232.
  20. ;    Aug 25, 1993    Changed 4Mc->3.2768Mc
  21. ;            Fixed interrupt problem (not re-entrant)
  22. ;             by disabling INTS in speak & morse
  23. ;    Jan 25, 1994    Added BUILDIT speech mode in preparation
  24. ;             for allophone based speech.  Currently
  25. ;             used for concatenating sounds of prosigns.
  26. ;    Feb 1, 1994    Changed 3.2768Mc->6.0Mc to support 8KHz data rate.
  27. ;    Mar 19, 1994    Added SET Option. Commented out to disable.
  28. ;    Apr 16, 1994    Fixed char rate bug when changed from default.
  29. ;    Apr 20, 1994    Added programmed delay before and after speaking
  30. ;    Apr 22, 1994    Version 1.0
  31. ;
  32. ;---------------------------------------------------------------------
  33. ;
  34. ;    Select options using ext_int0
  35. ;    Options are:
  36. ;    Speed
  37. ;        5@16
  38. ;        13@18
  39. ;        20@23
  40. ;    Toggle
  41. ;        SPEECH
  42. ;    Random Chars
  43. ;    Random Groups of five chars
  44. ;    Sequence Chars
  45. ;    Toggle Set (see SUBSET; not enabled)
  46. ;        LETTERS
  47. ;        NUMBERS
  48. ;        PROSIGNS
  49. ;        PUNCTUATION
  50. ;**        PROGRESSIONS
  51. ;**        COMPLEMENTS
  52. ;    ** = not yet implemented...
  53. ;
  54. ;
  55.  
  56.  
  57.  
  58. #INCLUDE "ISR_INIT.TXT"
  59.  
  60.  
  61. ;**************************************************************
  62. ;
  63. ; MAIN LOOP
  64. ;
  65.  
  66. MAIN
  67.     CJNE    R4,#RAN,MODE0        ;if R4=Random then JMP RCHARS
  68.     LJMP    RCHARS
  69.  
  70. MODE0    CJNE    R4,#SEQ,MODE1        ;if R4=Sequence then JMP CYCLE
  71.     LJMP    CYCLE
  72.     
  73. MODE1    CJNE    R4,#GRP,MODE2        ;if R4=Group then JMP RGRP
  74.     LJMP    RGRP
  75.  
  76. MODE2    SJMP    MAIN
  77.  
  78. ;**************************************************************
  79. ;
  80. ; RCHARS - Random Characters
  81. ;
  82.     
  83. RCHARS
  84.     LCALL    RANDOM            ; GENERATE RANDOM INDEX
  85. TRUNC    MOV    A,PH
  86.     RR    A
  87.     RR    A
  88.     RR    A
  89.     MOV    COUNT,A            ; SAVE INDEX
  90.     CLR    C
  91.     SUBB    A,#SETSIZE        ; A <- A - C - #data
  92.     JNC    RCHARS            ; C=0 -> A>=SETSIZE
  93.                     ; for INDEX: 0..SETSIZE-1
  94.     MOV    A,COUNT
  95.     LCALL    SUBSET
  96.     JZ    RCHARS
  97.  
  98.     JNB    CODE,RCPO1
  99.     MOV    A,COUNT            ; restore index
  100.     LCALL   MORSE            ; sound code
  101.  
  102. RCPO1
  103.     JNB    SPEAK,RCPO2
  104.     MOV     A,COUNT                    ; restore index
  105.     LCALL   SPEECH            ; speak code
  106.  
  107. RCPO2
  108.     LJMP    MAIN            ; RESTART MAIN LOOP
  109.  
  110. ;**************************************************************
  111. ;
  112. ; RGRP - Random Groups
  113. ;
  114.  
  115. RGRP
  116.     PUSH    RH
  117.     PUSH    RL
  118.  
  119.     LCALL    RCODE
  120.     LCALL    RCODE
  121.     LCALL    RCODE
  122.     LCALL    RCODE
  123.     LCALL    RCODE
  124.  
  125.     LCALL    WORD_DLY
  126.  
  127.     POP    RL        ; Restore seed. psuedorandom,
  128.     POP    RH        ; so sequence will be the same...
  129.  
  130.     LCALL    RTALK
  131.     LCALL    RTALK
  132.     LCALL    RTALK
  133.     LCALL    RTALK
  134.     LCALL    RTALK
  135.  
  136.     LJMP    MAIN        ; RESTART MAIN LOOP
  137.  
  138. ;**************************************************************
  139. ;
  140. ; RCODE - Random Code SUBROUTINE for RGRP
  141. ;
  142.  
  143. RCODE    LCALL    RANDOM            ; GENERATE RANDOM INDEX
  144.     MOV    A,PH
  145.     RR    A
  146.     RR    A
  147.     RR    A
  148.     MOV    COUNT,A            ; SAVE INDEX
  149.     CLR    C
  150.     SUBB    A,#SETSIZE
  151.     JNC    RCODE            ;C=0 -> A>=SETSIZE
  152.                     ; for INDEX: 0..43
  153.                     ; for INDEX: 0..SETSIZE-1
  154.     MOV    A,COUNT
  155.     LCALL    SUBSET
  156.     JZ    RCODE
  157.  
  158.     MOV    A,COUNT            ; RESTORE INDEX
  159.     LCALL   MORSE            ; sound code
  160.     RET                ; DONE
  161.  
  162. ;**************************************************************
  163. ;
  164. ; RTALK - Random Talk SUBROUTINE for RGRP
  165. ;
  166.  
  167. RTALK    LCALL    RANDOM            ; GENERATE RANDOM INDEX
  168.     MOV    A,PH
  169.     RR    A
  170.     RR    A
  171.     RR    A
  172.     MOV    COUNT,A            ; SAVE INDEX
  173.     CLR    C
  174.     SUBB    A,#SETSIZE
  175.     JNC    RTALK            ; C=0 -> A>=SETSIZE
  176.                     ; for INDEX: 0..SETSIZE-1
  177.     MOV    A,COUNT
  178.     LCALL    SUBSET
  179.     JZ    RTALK
  180.  
  181.     MOV    A,COUNT            ; RESTORE INDEX
  182.     JNB    SPEAK,RTDONE
  183.     LCALL   SPEECH            ; speak code
  184.  
  185. RTDONE
  186.     RET                ; DONE
  187.  
  188. ;**************************************************************
  189. ;
  190. ; CYCLE - Cycle sequentially through character set
  191. ;
  192.  
  193. CYCLE
  194.     MOV     COUNT,#0
  195. NEXT_C  MOV     A,COUNT
  196.     LCALL    SUBSET
  197.     JZ    NEXT_C
  198.  
  199.     MOV    A,COUNT
  200.     JNB    CODE,CYC1
  201.     LCALL   MORSE            ; sound code
  202.  
  203. CYC1
  204.     JNB    SPEAK,CYC2        ; test if speak on
  205.     MOV     A,COUNT                    ; restore index
  206.     LCALL   SPEECH            ; speak code
  207.  
  208. CYC2
  209.     INC     COUNT
  210.     MOV    A,COUNT
  211.     CJNE    A,#SETSIZE,NEXT_C
  212.     LJMP    MAIN            ; RESTART MAIN LOOP
  213.  
  214.  
  215.  
  216. ;
  217. ;*************************************************************************
  218. ;
  219. ; RANDOM
  220. ;
  221. ; RANDOM NUMBERS BETWEEN 0 AND {26+10+3+4 = 43}-1 = 42
  222. ; i.e. mod 42
  223. ;
  224. ; Best bet is to generate seed by having 16 bit counter that
  225. ; increments until input at power up...this requires setting
  226. ; mode, or maybe just indicating when to start...
  227. ; 
  228. ; Some external asyncronous event must establish seed.
  229. ;   See EXT0 in INIT_ISR.
  230. ;
  231. ; Algorithm described in:
  232. ; The Art of Computer Programming Volume 2, Seminumerical Algorithms
  233. ;   Donald Knuth
  234. ;
  235. ; X <- (aX + c) mod m
  236. ;
  237. ; m = 65536
  238. ; c/m ~ 0.2113248654
  239. ; c odd
  240. ; 13.85 -> c = 13
  241. ; a > sqrt(m), a > m/100, a < m - sqrt(m)
  242. ; 256 < 655 < a < 65280
  243. ; a = 31415    {= 122*256 + 183}
  244. ;
  245. ; X <- (31415 * X + 13) mod 65536
  246. ;
  247. ; NOTE: that the arithmetic done in a 16 bit word
  248. ; is mod 2^16 = 65536
  249. ;
  250. ; A * B = (AL + 2^8 * AH) * (BL + 2^8 * BH)
  251. ;       = AL * BL + 2^8(AL * BH + AH * BL) + 2^16(AH * BH)
  252. ; A * 31415 = AL * 183 + 2^8(AL * 122 + AH * 183) + 2^16(AH * 122)
  253. ; 
  254.  
  255. RANDOM
  256.     MOV    A,RL
  257.     MOV    B,#183
  258.     MUL    AB        ; A[7..0],B[15..8] product bits
  259.     MOV    PL,A
  260.     MOV    PH,B
  261.  
  262.     MOV    A,RL
  263.     MOV    B,#122
  264.     MUL    AB
  265.     ADD    A,PH
  266.     MOV    PH,A
  267.  
  268.     MOV    A,RH
  269.     MOV    B,#183
  270.     MUL    AB
  271.     ADD    A,PH
  272.     MOV    PH,A
  273.  
  274.     CLR    C            ; NOW ADD c
  275.     MOV    A,PL
  276.     ADDC    A,#13
  277.     MOV    PL,A    
  278.     JNC    NOCARRY
  279.     INC    PH
  280. NOCARRY
  281.     MOV    RL,PL
  282.     MOV    RH,PH    
  283.     RET                ; DONE RANDOM
  284.  
  285. ;
  286. ;*************************************************************************
  287. ;
  288. ; Define code for MORSE SUBROUTINE
  289. ;
  290. ;
  291. ; numbers 5 bits
  292. ; punctuation 6 bits
  293. ; letters <= 4 bits
  294. ;
  295. ; b7  b6  b5    |   b[4:0] -> group
  296. ;---------------|--------------------------
  297. ;  0  0  d      |   number or prosign
  298. ;  0  1  d      |   punctuation or prosign
  299. ;  1  0  0      |   1 element letter
  300. ;  1  0  1      |   2 element letter
  301. ;  1  1  0      |   3 element letter
  302. ;  1  1  1      |   4 element letter
  303. ;        | 
  304. ; d => don't    | 1 => dah
  305. ;    care    | 0 => dit
  306. ; 
  307.  
  308. CODE_TBL
  309.  
  310. LETTERS
  311. MCA .DB 10100001B
  312. MCB .DB 11101000B
  313. MCC .DB 11101010B
  314. MCD .DB 11000100B
  315. MCE .DB 10000000B
  316. MCF .DB 11100010B
  317. MCG .DB 11000110B
  318. MCH .DB 11100000B
  319. MCI .DB 10100000B
  320. MCJ .DB 11100111B
  321. MCK .DB 11000101B
  322. MCL .DB 11100100B
  323. MCM .DB 10100011B
  324. MCN .DB 10100010B
  325. MCO .DB    11000111B
  326. MCP .DB 11100110B
  327. MCQ .DB 11101101B
  328. MCR .DB 11000010B
  329. MCS .DB 11000000B
  330. MCT .DB 10000001B
  331. MCU .DB 11000001B
  332. MCV .DB 11100001B
  333. MCW .DB 11000011B
  334. MCX .DB 11101001B
  335. MCY .DB 11101011B
  336. MCZ .DB 11101100B
  337.  
  338. NUMBERS
  339. MC1 .DB 00001111B
  340. MC2 .DB 00000111B
  341. MC3 .DB 00000011B
  342. MC4 .DB 00000001B
  343. MC5 .DB 00000000B
  344. MC6 .DB 00010000B
  345. MC7 .DB 00011000B
  346. MC8 .DB 00011100B
  347. MC9 .DB 00011110B
  348. MC0 .DB 00011111B
  349.  
  350. PUNCTUATION
  351. MCPP .DB 01010101B
  352. MCPC .DB 01110011B
  353. MCPQ .DB 01001100B
  354.  
  355. PROSIGNS
  356. MCSDN .DB 00010010B
  357. MCSSK .DB 01000101B
  358. MCSBT .DB 00010001B
  359. MCSAR .DB 00001010B
  360. MCSKN .DB 00010110B        ; <<< NOT PART OF TEST SET!
  361.  
  362.  
  363. SUBSET
  364. ;
  365. ; CHECKS IF CHARACTER INDEX IS IN AN ENABLED SUBSET
  366. ; RETURNS ACC=0 IF NOT ENABLED
  367. ; RETURNS ACC=1 IF ENABLED
  368. ;
  369. ;    CLR    C        
  370. ;    SUBB    A,#CONST    ; C=0 -> A>=CONST
  371. ;
  372. ;    CLR    C
  373. ;    SUBB    A,#26        ; A={0..25} -> LETTER
  374. ;    JC    IN_GL        ; C=1 -> A<26
  375. ;    MOV    A,COUNT
  376. ;    SUBB    A,#36        ; A={26..35} -> NUMBER    
  377. ;    JC    IN_GN        ; C=1 -> 26<=A<36
  378. ;    MOV    A,COUNT
  379. ;    SUBB    A,#39        ; A={36..38} -> PUNCTUATION
  380. ;    JC    IN_GP        ; C=1 -> 36<=A<39
  381. ;    MOV    A,COUNT
  382. ;    SUBB    A,#43        ; A={39..42} -> PRO-SIGN
  383. ;    JC    IN_GS        ; C=1 -> 39<=A<43
  384. ;IN_GL
  385. ;    JNB    GL,NOT_IN_SET
  386. ;    MOV    A,#YES
  387. ;    RET
  388. ;IN_GN
  389. ;    JNB    GN,NOT_IN_SET
  390. ;    MOV    A,#YES
  391. ;    RET
  392. ;IN_GP
  393. ;    JNB    GP,NOT_IN_SET
  394. ;    MOV    A,#YES
  395. ;    RET
  396. ;IN_GS
  397. ;    JNB    GS,NOT_IN_SET
  398. ;    MOV    A,#YES
  399. ;    RET
  400. ;NOT_IN_SET
  401. ;    MOV    A,#NO
  402. ;    RET
  403.  
  404.     MOV    A,#YES        ; always enabled for now...
  405.     RET
  406.  
  407. SPEECH
  408. ;
  409. ; INPUT ACC = index for sound table, which must match
  410. ;         order of code table
  411.  
  412.  
  413.     CLR    C
  414.     RLC    A        ;MUL BY 2 for 2 byte address entries in table
  415.     MOV    TMP2,A        ;save index by 2
  416.     MOV    DPTR,#SOUND_TBL
  417.  
  418.     MOVC    A,@A+DPTR
  419.     MOV    ADDR_H,A    ;save addrh
  420.  
  421.     MOV    A,TMP2        ;restore index by 2
  422.     INC    A        ;get rest of addr
  423.     MOVC    A,@A+DPTR
  424.     MOV    DPL,A
  425.     MOV    DPH,ADDR_H
  426. ;
  427. ; delay after code - before speaking
  428. ;
  429.     MOV    R7,DLY_B4
  430.     LCALL    DELAY
  431.     MOV    R7,DLY_B4
  432.     LCALL    DELAY
  433.     MOV    R7,DLY_B4
  434.     LCALL    DELAY
  435.     MOV    R7,DLY_B4
  436.     LCALL    DELAY
  437.  
  438.     MOV    TMP2,#0        ;start at entry 0
  439.  
  440. BLD_LOOP    
  441.     MOV    A,TMP2
  442.     MOVC    A,@A+DPTR
  443.     
  444.     CJNE    A,#PA1,TP2    ;test if 1mS pause
  445.     SJMP    PAUSE1
  446. TP2    CJNE    A,#PA10,TP3    ;test if 10mS pause
  447.     SJMP    PAUSE2
  448. TP3    CJNE    A,#PA100,TP4    ;test if 100mS pause
  449.     SJMP    PAUSE3
  450. TP4    CJNE    A,#PA300,TP5    ;test if 500mS pause
  451.     SJMP    PAUSE4
  452. TP5    CJNE    A,#PA500,TTERM    ;test if terminator (0FFH)
  453.     SJMP    PAUSE5
  454. TTERM    CJNE    A,#0FFH,BLD_MORE
  455. ;
  456. ; delay after speaking - before next code
  457. ;
  458.     MOV    R7,DLY_AR
  459.     LCALL    DELAY
  460.     MOV    R7,DLY_AR
  461.     LCALL    DELAY
  462.     MOV    R7,DLY_AR
  463.     LCALL    DELAY
  464.     MOV    R7,DLY_AR
  465.     LCALL    DELAY
  466.     RET            ; DONE
  467.  
  468.  
  469. BLD_MORE
  470.     LCALL    MAKESOUND
  471. BMORE    INC    TMP2
  472.     SJMP    BLD_LOOP
  473.  
  474.  
  475. ;
  476. ; These pauses are used in speech concatenation
  477. ;
  478.     
  479. PAUSE1
  480.     MOV    R7,#1
  481.     LCALL    DELAY
  482.     SJMP    BMORE
  483.  
  484. PAUSE2
  485.     MOV    R7,#10
  486.     LCALL    DELAY
  487.     SJMP    BMORE
  488.  
  489. PAUSE3
  490.     MOV    R7,#100
  491.     LCALL    DELAY
  492.     SJMP    BMORE
  493.  
  494. PAUSE4
  495.     MOV    R7,#150
  496.     LCALL    DELAY
  497.     MOV    R7,#150
  498.     LCALL    DELAY
  499.     SJMP    BMORE
  500.  
  501. PAUSE5
  502.     MOV    R7,#250
  503.     LCALL    DELAY
  504.     MOV    R7,#250
  505.     LCALL    DELAY
  506.     SJMP    BMORE
  507.  
  508. SOUND_TBL
  509. #INCLUDE "TABLE02.TXT"        ; Defines contatenations
  510.  
  511. MAKESOUND
  512. #INCLUDE "SPEAK.TXT"
  513.  
  514. MORSE
  515. #INCLUDE "MORSE.TXT"
  516.  
  517.  
  518.     .ORG    (0FFFFH-51)
  519.     .TEXT    "COPYRIGHT (C) 1994 KEN STATON. ALL RIGHTS RESERVED"
  520.  
  521.     .ORG    0FFFFH
  522.     .DB    0FFH
  523.     .END
  524.